get Facebook photos

Hi there,

im building a flash photo gallery that loads your facebook photo’s into the gallery. The gallery is working really good, but when i test it online, he wont load the images.

Here is how i get my data:

package remco.ui.photo.Facebook {

    import flash.events.*;
    import flash.display.*;
    import flash.net.*;
    import flash.system.Security;

    import com.serialization.json.JSON;

    public class FacebookAlbumLoader extends EventDispatcher {

        private static const GRAPH_URL:String="http://graph.facebook.com";

        private var photoSetID:String;
        private var dataArray:Array = new Array();
        private var object:Object;
        private var initialized:Boolean = false;

        private var urlRequest:URLRequest;
        private var urlLoader:URLLoader;

        public static const LOADED:String = "loaded";

        public function FacebookAlbumLoader(target:IEventDispatcher=null) {

            super(target);
            Security.loadPolicyFile("http://graph.facebook.com/crossdomain.xml");
            Security.loadPolicyFile("http://profile.ak.fbcdn.net/crossdomain.xml");
            Security.loadPolicyFile("http://api.facebook.com/crossdomain.xml")
            Security.allowDomain("*");
            Security.allowInsecureDomain("*");

        }

        public function load( photoSetID:String ):void {

            this.photoSetID = photoSetID;

            urlRequest = new URLRequest(GRAPH_URL + "/" + photoSetID + "/photos");
            urlLoader = new URLLoader(urlRequest);
            urlLoader.addEventListener(Event.COMPLETE, onComplete, false, 0, true);

        }

        private function onComplete(e:Event):void {

            object = JSON.deserialize(e.target.data);

            var i:int = 0;

            for each (var o:Object in object.data) {

                var imgOb:Object = new Object();
                imgOb.tmb = o.images[5].source;
                imgOb.img = o.images[0].source;

                dataArray.push(imgOb);

            };
            trace("FacebookAlbumLoader: \t dispatch LOADED");
            dispatchEvent(new Event(FacebookAlbumLoader.LOADED));
            initialized = true;

        }

        public function get init():Boolean {
            return initialized;
        }

        public function getImageData():Array {
            return dataArray;
        }

    }
}

am i missing something? help appreciated

Got the solution!

By loading the image, i forgot the LoaderContext

loader.load(urlrequest, new LoaderContext(true));